GPS Module

Library

The GPS Sensor requires the TinyGPS library which can be downloaded here – [TinyGPSPlus-0.94b]

Note

The GPS module talks to the satellite and hence a line of sight might help it to lock (Otherwise it might keep displaying INVALID location)

Circuit

The connection is fairly simple with just 4 pins on the GPS module (VCC, GND and Serial TX, RX)

Since we are using Softserial we connect the Serial TX to Pin 4 (RX of Arduino) and RX to Pin 3 (TX of Arduino)

VCC can be connected to 3.3V and GND to GND.

Code

The example can be found as part of the downloaded library itself. Arduino IDE -> File -> Example -> TinyGPSPlus-0.94b->DeviceExample

Change the GPSBaud to 9600 in the example above

#include <TinyGPS++.h>
#include <SoftwareSerial.h>
/*
This sample sketch demonstrates the normal use of a TinyGPS++ (TinyGPSPlus) object.
It requires the use of SoftwareSerial, and assumes that you have a
4800-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
*/
static const int RXPin = 4, TXPin = 3;
static const uint32_t GPSBaud = 9600;

// The TinyGPS++ object
TinyGPSPlus gps;

// The serial connection to the GPS device
SoftwareSerial ss(RXPin, TXPin);

void setup()
{
Serial.begin(115200);
ss.begin(GPSBaud);

Serial.println(F("DeviceExample.ino"));
Serial.println(F("A simple demonstration of TinyGPS++ with an attached GPS module"));
Serial.print(F("Testing TinyGPS++ library v. ")); Serial.println(TinyGPSPlus::libraryVersion());
Serial.println(F("by Mikal Hart"));
Serial.println();
}

void loop()
{
// This sketch displays information every time a new sentence is correctly encoded.
while (ss.available() > 0)
if (gps.encode(ss.read()))
displayInfo();

if (millis() > 5000 && gps.charsProcessed() < 10)
{
Serial.println(F("No GPS detected: check wiring."));
while(true);
}
}

void displayInfo()
{
Serial.print(F("Location: ")); 
if (gps.location.isValid())
{
Serial.print(gps.location.lat(), 6);
Serial.print(F(","));
Serial.print(gps.location.lng(), 6);
}
else
{
Serial.print(F("INVALID"));
}

Serial.print(F(" Date/Time: "));
if (gps.date.isValid())
{
Serial.print(gps.date.month());
Serial.print(F("/"));
Serial.print(gps.date.day());
Serial.print(F("/"));
Serial.print(gps.date.year());
}
else
{
Serial.print(F("INVALID"));
}

Serial.print(F(" "));
if (gps.time.isValid())
{
if (gps.time.hour() < 10) Serial.print(F("0"));
Serial.print(gps.time.hour());
Serial.print(F(":"));
if (gps.time.minute() < 10) Serial.print(F("0"));
Serial.print(gps.time.minute());
Serial.print(F(":"));
if (gps.time.second() < 10) Serial.print(F("0"));
Serial.print(gps.time.second());
Serial.print(F("."));
if (gps.time.centisecond() < 10) Serial.print(F("0"));
Serial.print(gps.time.centisecond());
}
else
{
Serial.print(F("INVALID"));
}

Serial.println();
}

Output

Location: 12.893712,77.618270 Date/Time: 6/21/2016 17:27:13.00
Location: 12.893712,77.618270 Date/Time: 6/21/2016 17:27:13.00
Location: 12.893712,77.618270 Date/Time: 6/21/2016 17:27:13.00
Location: 12.893712,77.618270 Date/Time: 6/21/2016 17:27:13.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893700,77.618270 Date/Time: 6/21/2016 17:27:14.00
Location: 12.893706,77.618270 Date/Time: 6/21/2016 17:27:15.00